黑客
登录
客服
网络安全
帖子详情

清理Internet临时文件如何做?

1172次浏览
2020-3-2 18:04:22发布
2020-6-8 18:50:42忆梦资源网忆梦资源网5级
浏览器工具选项中点击Internet选项,勾选所需删除的临时文件即可
2020-8-6 13:57:43黑客m黑客m8级
给个vbs
2020-8-6 13:58:03黑客m黑客m8级
'' Script to clear web browser cache data
'' 
''------------------------------------------------------
'' 2014 HillStone. All right reserved.

Set glbWshShell = CreateObject("WScript.Shell")
Set glbFSO = CreateObject("Scripting.FileSystemObject")
Set glbWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set glbRegOper = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")

glbLogFile = "hsClear.log"

Function InitLog
On Error Resume Next
If glbFSO.FileExists(glbLogFile) Then
Set f = glbFSO.GetFile(glbLogFile)
If f.Size > (10 * 1024 * 1024) Then
Set f = Nothing
glbFSO.DeleteFile glbLogFile, True
Else
Set f = Nothing
End If
End If
End Function

Function AddDefaultLog(LogContent)
AddLog glbLogFile, LogContent
End Function

Function AddLog(LogFileName, LogContent)
On Error Resume Next
Const ForAppending = 8
Dim f
Set f = glbFSO.OpenTextFile(LogFileName, ForAppending, True)
f.WriteLine LogContent
f.Close
Set f = Nothing
End Function
2020-8-6 13:58:22黑客m黑客m8级
Function GetOSMainVer
strComputer = "."
Set colOSes = glbWMIService.ExecQuery("select * from Win32_OperatingSystem")
For Each objOS in colOSes
'' WScript.Echo objOS.Version
AddDefaultLog(objOS.Version)
dot = InStr(objOS.Version, ".")
If dot = 0 Or dot=Null Then
GetOSMainVer = 0
Else
mainVer = Mid(objOS.Version, 1, dot - 1)
GetOSMainVer=CInt(mainVer)
End If
Exit For
Next
End Function

Function TerminateProcessByName(processName)
On Error Resume Next
Set colProcList = glbWMIService.ExecQuery("select * FROM Win32_Process WHERE Name=''"&processName&"''")
For Each proc in colProcList
AddDefaultLog("Terminate process (PID: "&CStr(proc.ProcessId)&"  "&processName&")")
proc.Terminate()
Next
WScript.Sleep 1000
End Function
2020-8-6 13:58:58黑客m黑客m8级
Function ClearChromeCache
On Error Resume Next
'' Terminate Chrome.exe
TerminateProcessByName("Chrome.exe")

'' Get cache directory
If GetOSMainVer < 6 Then '' Before Vista
strCacheDir = glbWshShell.ExpandEnvironmentStrings("%USERPROFILE%") & _
"\Local Settings\Application Data\Google\Chrome\User Data\Default"
Else '' After Vista
strCacheDir = glbWshShell.ExpandEnvironmentStrings("%LocalAppData%") & _
"\Google\Chrome\User Data\Default"
End If

AddDefaultLog(strCacheDir)

'' Clear cache
ClearDirectory(strCacheDir)
End Function

Function ClearSafariCache
On Error Resume Next

TerminateProcessByName("Safari.exe")

If GetOSMainVer < 6 Then
UserDir = glbWshShell.ExpandEnvironmentStrings("%USERPROFILE%") & _
"\Application Data\Apple Computer\Safari"
CacheDir = glbWshShell.ExpandEnvironmentStrings("%USERPROFILE%") & _
"\Local Settings\Application Data\Apple Computer\Safari"
Else
UserDir = glbWshShell.ExpandEnvironmentStrings("%USERPROFILE%") & _
"\AppData\Roaming\Apple Computer\Safari"
CacheDir = glbWshShell.ExpandEnvironmentStrings("%LocalAppData%") & _
"\Apple Computer\Safari"
End If

AddDefaultLog("Safari user directory: " & UserDir)
AddDefaultLog("Safari cache directory: " & CacheDir)

Dirs = Array(UserDir, CacheDir)
For Each directory in Dirs
ClearDirectory(directory)
Next
End Function

Function GetIEMainVersion
Const HKEY_LOCAL_MACHINE = &H80000002
strKeyPath = "Software\Microsoft\Internet Explorer"

On Error Resume Next
MVer = 0
strVersion = "0.0"
glbRegOper.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, "Version", strVersion
dot = InStr(strVersion, ".")
If dot = 0 Or dot=Null Then
GetIEMainVersion = 0
Else
mainVer = Mid(strVersion, 1, dot - 1)
GetIEMainVersion=CInt(mainVer)
End If
End Function
2020-8-6 13:59:26黑客m黑客m8级
Function ClearIECache
On Error Resume Next
'' Terminate IExplore.exe
TerminateProcessByName("iexplore.exe")

'' Clear typed URL history
Const HKEY_CURRENT_USER = &H80000001
strKeyPath = "Software\Microsoft\Internet Explorer\TypedURLs"

glbRegOper.EnumValues HKEY_CURRENT_USER, strKeyPath, arrValueNames, arrValueTypes
For i=0 to UBound(arrValueNames)
glbRegOper.GetStringValue HKEY_CURRENT_USER, strKeyPath, arrValueNames(i), strValue
AddDefaultLog("Remove URL: "&strValue)
glbRegOper.DeleteValue HKEY_CURRENT_USER, strKeyPath, arrValueNames(i)
Next

'' Run(cmdLine, intWindowStyle, bWaitOnReturn)
'' intWindowStyle: 0, Hides the window and  activates another window.
uIeMainVer = GetIEMainVersion
If uIeMainVer > 6 Then
glbWshShell.Run "rundll32 InetCpl.cpl, ClearMyTracksByProcess 255", 0, False
Else
AddDefaultLog("IE main version is less than or equal to 6")
End If

End Function

Function Clear360Cache
'' For 360se, we should clear IE cache as well. But in FR3465 we always
'' clear cache for 360se and  IE, so we just delete 360se-specific files
'' here.
On Error Resume Next

TerminateProcessByName("360se.exe")

'' This folder requires extremely high privilege.
'' For now, we cannot delete files inside this folder.
CacheDir = glbWshShell.ExpandEnvironmentStrings("%AppData%") & _
"\360se6\User Data\Default"

AddDefaultLog("Clear directory: " & CacheDir)

ClearDirectory(CacheDir)
ClearDirectory(CacheDir & "\CacheIE")
End Function

Function ClearSogouCache
'' Need clear IE cache too.
On Error Resume Next
TerminateProcessByName("sogouexplorer.exe")

CacheDir = glbWshShell.ExpandEnvironmentStrings("%AppData%") & _
"\SogouExplorer"

ClearDirectory(CacheDir & "\WebKit\Default")
ClearDirectory(CacheDir & "\DailyBackup")
ClearDirectory(CacheDir)

'' Exceptional terminated url cache: HKEY_CURRENT_USER\Software\SogouExplorer\TabSnapshot
Const HKEY_CURRENT_USER = &H80000001
strKeyPath = "Software\SogouExplorer\TabSnapshot"
glbRegOper.SetDWORDValue HKEY_CURRENT_USER, strKeyPath, "Status", 0
glbRegOper.DeleteKey HKEY_CURRENT_USER, strKeyPath&"\URL"

'' files = Array("uhistory.db", "HistoryUrl.db", "HistoryUrl3.db", "FormData3.dat", "FormData.db", "SogouCache.db")
'' For Each cache_file in files
'' file_path = CacheDir & "\" & cache_file
'' If glbFSO.FileExists(file_path) Then
'' AddDefaultLog("Begin DeleteFile: " & objFile.Path)
'' glbFSO.delete file_path, True
'' End If
'' Next
End Function

Function ClearDirectory(DirPath)
On Error Resume Next
If glbFSO.FolderExists(DirPath) Then
Set objFolder = glbFSO.GetFolder(DirPath)
For Each objFile in objFolder.Files
AddDefaultLog("Begin DeleteFile: " & objFile.Path)
glbFSO.DeleteFile objFile.Path, True
Next
End If
End Function



InitLog
AddDefaultLog("-----------------------------------------------------------------")
AddDefaultLog("-  Clear Browser Cache begin at " & CStr(Date) &" "& CStr(Time) & " -")
AddDefaultLog("-----------------------------------------------------------------")
ClearChromeCache
2020-8-6 13:59:34黑客m黑客m8级
ClearIECache
ClearSafariCache
ClearSogouCache
Clear360Cache
我来回答
清理Internet临时文件如何做?

    取消

问答活动
最新帖子
推荐帖子

黑客技术 黑客软件 黑客教程 黑客书籍

关于我们 | 免责声明 | 学员守则 | 广告服务 | 联系我们

©2013-2020 xf1433.com 版权所有

本站资源仅供用于学习和交流,请遵循相关法律法规